Two examples of a simple REST call in PeopleCode.

The first is undocumented, but provides the response code unlike the second:

Local Message &Request;
Local boolean &b;
&Request = CreateMessage(Operation.IB_GENERIC_REST_POST);
&Request.OverrideURIResource("https://api.example.com/v1/example");
&b = &Request.AddSegmentHeader("accept", "application/json");
&b = &Request.AddSegmentHeader("authorization", "Basic invalidlY2EtNWRjNS00ZTI1LWI5XWEtMTZiMzc0ZGM1OGJhOmVhZjQ1NDE5LTkyNTUtNDFlZi05NTdkLWVhNDlmNGI1MGRkMw==");

Local Message &Response;
&Response = %IntBroker.ProvideRestTest(&Request, "GET");

MessageBox(0, "", 0, 0, "response code: " | String(&Response.HTTPResponseCode) | ", content: " | &Response.GetContentString());

The second is documented in PeopleBooks:

Local Message &Request;
&Request = CreateMessage(Message.IB_GENERIC);
&Request.IBInfo.IBConnectorInfo.ConnectorName = "HTTPTARGET";
&Request.IBInfo.IBConnectorInfo.ConnectorClassName = "HttpTargetConnector";
   
Local boolean &b;
&b = &Request.IBInfo.IBConnectorInfo.AddConnectorProperties("Method", "GET", %HttpProperty);
&b = &Request.IBInfo.IBConnectorInfo.AddConnectorProperties("URL", "https://api.example.com/v1/example", %HttpProperty);
&b = &Request.IBInfo.IBConnectorInfo.AddConnectorProperties("accept", "application/json", %Header);
&b = &Request.IBInfo.IBConnectorInfo.AddConnectorProperties("authorization", "Basic invalidlY2EtNWRjNS00ZTI1LWI5XWEtMTZiMzc0ZGM1OGJhOmVhZjQ1NDE5LTkyNTUtNDFlZi05NTdkLWVhNDlmNGI1MGRkMw==", %Header);
   
Local Message &Response;
&Response = %IntBroker.ConnectorRequest(&Request, True);
If &Response.ResponseStatus = %IB_Status_Success Then
   Local XmlDoc &XMLResponse = &Response.GetXmlDoc();
Else
   MessageBox(0, "", 0, 0, &Response.IBException.ToString());
End-If;